G1: Define Matrices
Data Calc NGroups=3
Begin Matrices;
A full 1 1 free
C full 1 1 free
E full 1 1 free
T full 1 1 free ! moderator-linked A component
U full 1 1 free ! moderator-linked C component
V full 1 1 free ! moderator-linked E component
M full 1 1 free ! grand mean
B full 1 1 free ! moderator-linked means model
H full 1 1
R full 1 1     ! twin 1 moderator (definition variable)
S full 1 1     ! twin 2 moderator (definition variable)
End Matrices;
Ma T 0
Ma U 0
Ma V 0
Ma M 0
Ma B 0
Ma A 1
Ma C 1
Ma E 1
Matrix H .5
Options NO_Output
Intervals @95 a 1 1		! Genetic components of variance 
Intervals @95 c 1 1 		! SE components of variance 
Intervals @95 e 1 1   		! NE components of variance
Intervals @95 t 1 1		! Genetic components of variance GXE
Intervals @95 u 1 1 		! SE components of variance  moderatorXC
Intervals @95 v 1 1   		! NE components of variance moderarotXE
End
 
G2: MZ
Data NInput_vars=6 NObservations=0
Missing =-999.00
RE File=liage93.dat
Labels id zyg p1 p2 m1 m2
Select if zyg = 1 /
Select p1 p2 m1 m2 /
Definition m1 m2 /
Matrices = Group 1
Means M + B*R |M + B*S /
Covariance      
(A+T*R)*(A+T*R)' + (C+U*R)*(C+U*R)' + (E+V*R)*(E+V*R)'  | (A+T*R)*(A+T*S)' +  (C+U*R)*(C+U*S)'  _
(A+T*S)*(A+T*R)' + (C+U*S)*(C+U*R)' | (A+T*S)*(A+T*S)' + (C+U*S)*(C+U*S)' + (E+V*S)*(E+V*S)' /
!twin 1 moderator variable
Specify R -1
!twin 2 moderator variable
Specify S -2
Options NO_Output
End
 
G3: DZ
Data NInput_vars=6 NObservations=0
Missing =-999.00
RE File=liage93.dat
Labels id zyg p1 p2 m1 m2
Select if zyg = 2 /
Select p1 p2 m1 m2 /
Definition m1 m2 /
Matrices = Group 1
Means M + B*R |M + B*S /
Covariance      
(A+T*R)*(A+T*R)' + (C+U*R)*(C+U*R)' + (E+V*R)*(E+V*R)'  | H@(A+T*R)*(A+T*S)' +  (C+U*R)*(C+U*S)'  _
H@(A+T*S)*(A+T*R)' + (C+U*S)*(C+U*R)' | (A+T*S)*(A+T*S)' + (C+U*S)*(C+U*S)' + (E+V*S)*(E+V*S)' /
!twin 1 moderator variable
Specify R -1
!twin 2 moderator variable
Specify S -2

options multiple Issat rs
End